1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
|
DOUBLE PRECISION FUNCTION ZLA_GERCOND_X( TRANS, N, A, LDA, AF,
$ LDAF, IPIV, X, INFO,
$ WORK, RWORK )
*
* -- LAPACK routine (version 3.2.1) --
* -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
* -- Jason Riedy of Univ. of California Berkeley. --
* -- April 2009 --
*
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley and NAG Ltd. --
*
IMPLICIT NONE
* ..
* .. Scalar Arguments ..
CHARACTER TRANS
INTEGER N, LDA, LDAF, INFO
* ..
* .. Array Arguments ..
INTEGER IPIV( * )
COMPLEX*16 A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
DOUBLE PRECISION RWORK( * )
* ..
*
* Purpose
* =======
*
* ZLA_GERCOND_X computes the infinity norm condition number of
* op(A) * diag(X) where X is a COMPLEX*16 vector.
*
* Arguments
* =========
*
* TRANS (input) CHARACTER*1
* Specifies the form of the system of equations:
* = 'N': A * X = B (No transpose)
* = 'T': A**T * X = B (Transpose)
* = 'C': A**H * X = B (Conjugate Transpose = Transpose)
*
* N (input) INTEGER
* The number of linear equations, i.e., the order of the
* matrix A. N >= 0.
*
* A (input) COMPLEX*16 array, dimension (LDA,N)
* On entry, the N-by-N matrix A.
*
* LDA (input) INTEGER
* The leading dimension of the array A. LDA >= max(1,N).
*
* AF (input) COMPLEX*16 array, dimension (LDAF,N)
* The factors L and U from the factorization
* A = P*L*U as computed by ZGETRF.
*
* LDAF (input) INTEGER
* The leading dimension of the array AF. LDAF >= max(1,N).
*
* IPIV (input) INTEGER array, dimension (N)
* The pivot indices from the factorization A = P*L*U
* as computed by ZGETRF; row i of the matrix was interchanged
* with row IPIV(i).
*
* X (input) COMPLEX*16 array, dimension (N)
* The vector X in the formula op(A) * diag(X).
*
* INFO (output) INTEGER
* = 0: Successful exit.
* i > 0: The ith argument is invalid.
*
* WORK (input) COMPLEX*16 array, dimension (2*N).
* Workspace.
*
* RWORK (input) DOUBLE PRECISION array, dimension (N).
* Workspace.
*
* =====================================================================
*
* .. Local Scalars ..
LOGICAL NOTRANS
INTEGER KASE
DOUBLE PRECISION AINVNM, ANORM, TMP
INTEGER I, J
COMPLEX*16 ZDUM
* ..
* .. Local Arrays ..
INTEGER ISAVE( 3 )
* ..
* .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
* ..
* .. External Subroutines ..
EXTERNAL ZLACN2, ZGETRS, XERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, MAX, REAL, DIMAG
* ..
* .. Statement Functions ..
DOUBLE PRECISION CABS1
* ..
* .. Statement Function Definitions ..
CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
* ..
* .. Executable Statements ..
*
ZLA_GERCOND_X = 0.0D+0
*
INFO = 0
NOTRANS = LSAME( TRANS, 'N' )
IF ( .NOT. NOTRANS .AND. .NOT. LSAME( TRANS, 'T' ) .AND. .NOT.
$ LSAME( TRANS, 'C' ) ) THEN
INFO = -1
ELSE IF( N.LT.0 ) THEN
INFO = -2
END IF
IF( INFO.NE.0 ) THEN
CALL XERBLA( 'ZLA_GERCOND_X', -INFO )
RETURN
END IF
*
* Compute norm of op(A)*op2(C).
*
ANORM = 0.0D+0
IF ( NOTRANS ) THEN
DO I = 1, N
TMP = 0.0D+0
DO J = 1, N
TMP = TMP + CABS1( A( I, J ) * X( J ) )
END DO
RWORK( I ) = TMP
ANORM = MAX( ANORM, TMP )
END DO
ELSE
DO I = 1, N
TMP = 0.0D+0
DO J = 1, N
TMP = TMP + CABS1( A( J, I ) * X( J ) )
END DO
RWORK( I ) = TMP
ANORM = MAX( ANORM, TMP )
END DO
END IF
*
* Quick return if possible.
*
IF( N.EQ.0 ) THEN
ZLA_GERCOND_X = 1.0D+0
RETURN
ELSE IF( ANORM .EQ. 0.0D+0 ) THEN
RETURN
END IF
*
* Estimate the norm of inv(op(A)).
*
AINVNM = 0.0D+0
*
KASE = 0
10 CONTINUE
CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
IF( KASE.NE.0 ) THEN
IF( KASE.EQ.2 ) THEN
* Multiply by R.
DO I = 1, N
WORK( I ) = WORK( I ) * RWORK( I )
END DO
*
IF ( NOTRANS ) THEN
CALL ZGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
$ WORK, N, INFO )
ELSE
CALL ZGETRS( 'Conjugate transpose', N, 1, AF, LDAF, IPIV,
$ WORK, N, INFO )
ENDIF
*
* Multiply by inv(X).
*
DO I = 1, N
WORK( I ) = WORK( I ) / X( I )
END DO
ELSE
*
* Multiply by inv(X**H).
*
DO I = 1, N
WORK( I ) = WORK( I ) / X( I )
END DO
*
IF ( NOTRANS ) THEN
CALL ZGETRS( 'Conjugate transpose', N, 1, AF, LDAF, IPIV,
$ WORK, N, INFO )
ELSE
CALL ZGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
$ WORK, N, INFO )
END IF
*
* Multiply by R.
*
DO I = 1, N
WORK( I ) = WORK( I ) * RWORK( I )
END DO
END IF
GO TO 10
END IF
*
* Compute the estimate of the reciprocal condition number.
*
IF( AINVNM .NE. 0.0D+0 )
$ ZLA_GERCOND_X = 1.0D+0 / AINVNM
*
RETURN
*
END
|